T-lines with reactive terminations 
*reactive_terms.sp
*
*uncomment the desired elements to run simulations
*
*within ngspice: >  source reactive_terms.sp
*

*input source with 1ns delay, 1nS edges, 50ns pulse width, 100ns cycle time
Vin vin 0 1.0 PULSE(0 1.0 1e-9 0.1nS 0.1nS 50e-9 100e-9)

*source output impedance 
rsrc vin tline_in 50     

*the transmission line, 50 ohm, 2ns electrical length
t1 tline_in 0 tline_out 0  z0=50  td=2ns

*resistive termaination at end of T-line
*rt tline_out 0 100  

*resistor in series with inductor
*rt    tline_out tie 100  
*lload tie         0 100nh

*resistor in series with capacitor
*rt    tline_out tie 50  
*cload tie         0 100pf

*capacitor at end of T-line
cload tline_out 0 100pf

*inductor at end of T-line
*lload tline_out 0 100nh

*parallel resonant network
*should resonate at frequency of Fo=1/(2*pi*sqrt(L*C))=50.35 neglecting
*the loading effects of the t-line
*cload tline_out 0 100pf
*lload tline_out 0 100nh

*series resonant network
*same resonant frequency
*check waveform at tie_pt
*lload tline_out  tie_pt0 50nh
*cload tie_pt0         0 5pf

.control
  set hcopydevtype=postscript
  set hcopypscolor=0
  set color0=rgb:f/f/f
  set color1=rgb:0/0/0
  op
  tran 100ps 50ns
  plot  V(tline_in) V(tline_out)  xl 1ns 50ns
*  plot  V(tline_in) V(tline_out) V(tie_pt0)  xl 1ns 50ns
.endc

.end