T line with various t-line stub matches
*Stubs are positioned 1.03 meters (stub position A) or
*3.155m (stub position B) away from the reactive load 
*of 75+j25. 
*Solutions use open circuited and short circuited stubs 
*in a series configuration.

*transmitter with 50 ohm output
Vin vin 0 ac 1.0 sin(0 1.0 29.6e6)
rsrc  vin  tl_in   50 

*arbitrarily long (about 20 meters) piece of t-line
t1   tl_in 0   tl_j1 0   z0=50 td=100ns

*
*uncomment the selected configuration as desired
*
******* solution open ckt stub position A ***********
*t-line stub match, open circuited end and 2.38m long
*this represents an inductance of +j0.6
t3   tl_j1 tl_j2   tl3_out tl3_gnd   z0=50 td=11.34ns

*1.03 meter long t-line 
*real part of the impedance here is 50 ohms
t2   tl_j2 0   tl_out 0   z0=50 td=4.91ns

*prevent floating node problems
r98  tl3_out  0 10e6
r99  tl3_gnd  0 10e6
*****************************************************

******* solution open ckt stub position B ***********
*t-line stub match, open circuited end and 2.38m long
*this represents a capacitance of -j0.6
*t3   tl_j1 tl_j2   tl3_out tl3_gnd   z0=50 td=5.52ns

*3.155 meter long t-line 
*real part of the impedance here is 50 ohms
*t2   tl_j2 0   tl_out 0   z0=50 td=15.02ns

*prevent floating node problems
*r98  tl3_out  0 10e6
*r99  tl3_gnd  0 10e6
******************************************************

******* solution short ckt stub position A ***********
*t-line stub match, short circuited end and 0.61m long
*this represents a inductance of +j0.6
*t3   tl_j1 tl_j2   tl3_out tl3_out   z0=50 td=2.9ns

*1.03 meter long t-line 
*real part of the impedance here is 50 ohms
*t2   tl_j2 0   tl_out 0   z0=50 td=4.91ns

*prevent floating node problems
*r99  tl3_out  0 10e6
******************************************************

******* solution short ckt stub position B ***********
*t-line stub match, short circuited end and 2.935m long
*this represents a capacitance of -j0.6
*t3   tl_j1 tl_j2   tl3_out tl3_out   z0=50 td=13.98ns

*3.155 meter long t-line 
*real part of the impedance here is 50 ohms
*t2   tl_j2 0   tl_out 0   z0=50 td=15.02ns

*prevent floating node problems
*r99  tl3_out  0 10e6
******************************************************

*complex load 75+25j at 29.6Mhz
rload tl_out      join_load   75       
lload join_load   0           134.5nH 

.control
 set hcopydevtype=postscript
* set hcopydev=kec3112-clr
 set hcopypscolor=true
 set color0=rgb:f/f/f
 set color1=rgb:0/0/0
 ac lin 100 10M 50Meg 
* tran 10nS  250nS  

  plot vm(vin) vm(vin,tl_in)  vm(tl_in)
* hardcopy temp.ps  vm(vin) vm(vin,tl_in)  vm(join_in)
.endc

.end