shunt_stub_full_ex.sp

*Full example matching a 1/2 wave dipole at 280Mhz with shunt
*stubs (both open and short-circuited style) at the closest
*position (A).

*The reactive load representing the antenna is 87+j100.
*Lambda for the selected cable (RG-58) at 280Mhz is .707 meters.
*System impedance is 50 ohms.

*Both stubs are located (position A) at: 
* 0.226 lambda = 6.3 inches from antenna 
*The stubs both represent -j1.65 
*Short circuit stub : 0.086 lambda or 2.40 inches
*Open circuit stub  : 0.336 lambda or 9.35 inches 

*transmitter with 50 ohm output at 280Mhz
Vin   vin 0 ac 1.0 sin(0 1.0 280e6) ;280Mhz transmitter
rsrc  vin  t1_in   50               ;transmitter output impedance

*arbitrarily long T-line (about 4.25 meters) from transmitter to stub
t1   t1_in   0   t1_out t1_out_rtn   z0=50 F=280Meg  NL=3.0

********************************************************
*uncomment the selected configuration below as desired *
********************************************************

************ position A open ckt stub ****************
*Open circuit stub  : 0.336 lambda or 9.35 inches 

*T-line from antenna to stub
*t2   t1_out  t1_out_rtn  t2_out  0           z0=50 F=280Meg NL=0.226
*0.336 lambda shunt (open) stub 
*t3   t1_out  t1_out_rtn  t3_out  t3_out_rtn  z0=50 F=280Meg NL=0.336

*to prevent floating nodes 
*r98  t3_out      0 10e6
*r99  t3_out_rtn  0 10e6
*r95  t1_out      0 10e6
*****************************************************

************ position A short ckt stub ****************
*Short circuit stub: 0.086 lambda or 2.4 inches 

*line from antenna to stub
t2   t1_out  t1_out_rtn  t2_out 0  z0=50  F=280Meg  NL=.226
*0.086 lambda shunt (shorted) stub 
t3   t1_out  t1_out_rtn  t3_out_short  t3_out_short  z0=50  F=280Meg NL=.086

*to prevent floating nodes
r99  t3_out_short      0 10e6
r98  t1_out            0 10e6
*****************************************************

*complex load 87 + j100 @ 280Mhz
rload t2_out      join_load   87       
lload join_load   0           57nH

.control
* set hcopydevtype=postscript
* set hcopydev=kec3112-clr
* set hcopypscolor=true
 set color0=rgb:f/f/f
 set color1=rgb:0/0/0
 ac lin 200 250Meg 300Meg 

*plot voltages and currents at t1's input
plot  vm(vin,t1_in) vm(t1_in)

*plot T-line input impedance directly
plot (50*vm(t1_in))/(vm(vin,t1_in))

hardcopy temp.ps  (50*vm(t1_in))/(vm(vin,t1_in))
*hardcopy temp.ps  vm(vin) vm(vin,t1_in)  vm(join_in)
.endc

.end