*Inverted V antenna at 29.6Mhz that represents a complex 
*impedance of 75+25j
*uses matching with lumped element, shorted and open stubs
*stub is positioned 1.06 meters from the load

*transmitter with 50 ohm output
*Vin vin 0 ac 1.0 sin(0 1.0 29.6e6)
Vin vin 0 ac sin(0 1.0 29.6e6)
rsrc  vin  tl_in   50 

*arbitrarily long (3 wavelengths ~ 20 meters) piece of coax 
t1 tl_in     0 tl_j1      0  z0=50 F=29.6Meg NL=3    
*1.06 meter long coax is 0.149 lambda
t2 tl_j2     0 tl_out     0  z0=50 F=29.6Meg NL=0.1495

*insert matching inductor at the 1.06 meter point
lmatch tl_j1   tl_j2  155nH 
*insert matching shorted coaxial stub at the 1.06 meter point
*t3 tl_j1  tl_j2    tie1 tie1  z0=50 F=29.6Meg NL=0.0833
*r90  tie1 0 10Meg
*insert matching open coaxial stub at the 1.06 meter point
*t3 tl_j1  tl_j2    tie1 tie2  z0=50 F=29.6Meg NL=0.304
*r90  tie1 0    10Meg
*r91  tie2 0    10Meg

*complex load 75+25j at 29.6Mhz
rload tl_out      join_load   75       
lload join_load   0           134.5nH

.control
 set hcopydevtype=postscript
 *set hcopydev=kec3112-clr
 set hcopypscolor=true
 set color0=rgb:f/f/f
 set color1=rgb:0/0/0
 ac lin 100 10M 50Meg 
 plot vm(vin) vm(vin,tl_in)  vm(tl_in) vm(tl_j1)
 plot vm(tl_in)/(vm(vin,tl_in)/50)
 hardcopy temp.ps  vm(tl_in) vm(vin,tl_in)  
.endc

.end