T-line with various shunt stub matches

*Open and short circuit shunt stubs at both positions are given 
*Stubs are located at: 
* 0.194 lambda = 1.38 meters (stub position A) OR
* 0.398 lambda = 2.82 meters (stub position B) 

*For this problem, lambda is given as 7.09 meters at 29.7Mhz
*The reactive load representing the antenna is given as 75+j25. 
*System impedance is 50 ohms.

*transmitter with 50 ohm output at 29.6Mhz
Vin   vin 0 ac 1.0 sin(0 1.0 29.6e6)
rsrc  vin  t1_in   50 ;transmitter output impedance

*arbitrarily long T-line (about 21 meters) from transmitter to stub
t1   t1_in   0   t1_out t1_out_rtn   z0=50 F=29.6Meg  NL=3.0

********************************************************
*uncomment the selected configuration below as desired *
********************************************************

************ position A open ckt stub ****************
*position A:        0.194 lambda or 1.38m from antenna
*open circuit stub: 0.414 lambda or 2.94m long
*stub represents inductive susceptance of B=-j0.6

*T-line from antenna to stub
t2   t1_out  t1_out_rtn  t2_out  0           z0=50 F=29.6Meg NL=.194
*0.414 lambda shunt (open) stub 
t3   t1_out  t1_out_rtn  t3_out  t3_out_rtn  z0=50 F=29.6Meg NL=.414

*to prevent floating nodes 
r98  t3_out      0 10e6
r99  t3_out_rtn  0 10e6
r95  t1_out      0 10e6
*****************************************************

************ position A short ckt stub ****************
*position A:         0.194 lambda or 1.375m from antenna
*short circuit stub: 0.164 lambda or 1.163m long
*stub represents inductanve susceptance of B=-j0.6

*line from antenna to stub
*t2   t1_out  t1_out_rtn  t2_out 0  z0=50  F=29.6Meg  NL=.194
*0.164 lambda shunt (shorted) stub 
*t3   t1_out  t1_out_rtn  t3_out_short  t3_out_short  z0=50  F=29.6Meg NL=.164

*to prevent floating nodes
*r99  t3_out_short      0 10e6
*r98  t1_out            0 10e6
*****************************************************

************ position B open ckt stub ****************
*position B:        0.398 lambda or 2.822m from antenna
*open circuit stub: 0.086 lambda or 0.61m long
*stub represents capactive susceptance of B=j0.6

*line from antenna to stub
*t2   t1_out  t1_out_rtn  t2_out  0           z0=50 F=29.6Meg NL=.398
*0.086 lambda shunt (shorted) stub 
*t3   t1_out  t1_out_rtn  t3_out  t3_out_rtn  z0=50 F=29.6Meg NL=.086

*to prevent floating node problems
*r98  t3_out            0 10e6
*r99  t3_out_rtn        0 10e6
*r95  t1_out            0 10e6
*****************************************************

************ position B short ckt stub ****************
*position B:        0.398 lambda or 2.822m from antenna
*short circuit stub: 0.336 lambda or 2.38m long
*stub represents capactive susceptance of B=j0.6

*line from antenna to stub
*t2   t1_out  t1_out_rtn  t2_out 0  z0=50  F=29.6Meg NL=.398
*0.086 lambda shunt (shorted) stub 
*t3   t1_out  t1_out_rtn  t3_out_short  t3_out_short z0=50 F=29.6Meg NL=.336

*to prevent floating node problems
*r99  t3_out_short      0 10e6
*r98  t1_out            0 10e6
*****************************************************

*complex load 75+25j at 29.6Mhz
rload t2_out      join_load   75       
lload join_load   0           134.5nH 

.control
* set hcopydevtype=postscript
* set hcopydev=kec3112-clr
* set hcopypscolor=true
 set color0=rgb:f/f/f
 set color1=rgb:0/0/0
 ac lin 200 20Meg 40Meg 

*plot voltages and currents at t1's input
plot  vm(vin,t1_in) vm(t1_in)

*plot T-line input impedance directly
plot (50*vm(t1_in))/(vm(vin,t1_in))

*hardcopy temp.ps  vm(vin) vm(vin,t1_in)  vm(join_in)
.endc

.end